Contar veces que se repite un valor en Excel

En los siguientes ejemplo podremos contar las veces que se repite un valor en Excel, para ello primero buscaremos repeticiones en un rango,  contar por columnas, y luego poder contar en varias hojas, observemos:

En este ejemplo se realizará la búsqueda de la palabra "Tegucigalpa", notemos que la búsqueda será por la coincidencia completa del valor de la celda, y que la búsqueda a realizarse no distingue entre mayúsculas y minúsculas.

Contar veces que se repite un valor usando CONTAR.SI

Notemos en el ejemplo que podríamos emplear:

=CONTAR.SI(E1:G17,B3)

o

=CONTAR.SI(INDIRECTO("Hoja2!E1:G17"),B3)

En el primer caso recurrimos a la función CONTAR.SI para buscar el valor que contiene B3 (en el ejemplo "Tegucigalpa") dentro del rango de celdas E1:G17, en la misma hoja.

En la segunda fórmula se introduce la función INDIRECTO, y la referencia a la hoja2, la función indirecto tiene como finalidad cambiar un texto (que se distingue por estar rodeado por comillas dobles)   en una referencia a un rango, estamos introduciendo esto debido a que podríamos modificar dicho texto o hacerlo que dependa de  otra celda.

Contar veces que se repite un valor por hoja

Continuando con el ejemplo anterior podemos emplear las fórmulas:

En D6:   =CONTAR.SI(INDIRECTO("'"&B6&"'!E1:G17"),B3)

En D7:   =CONTAR.SI(INDIRECTO("'"&B7&"'!E1:G17"),B3)

En D8:   =CONTAR.SI(INDIRECTO("'"&B8&"'!E1:G17"),B3)

Como B6 contiene "Hoja1", en D6 aparecerá las veces que aparece el valor "Tegucigalpa" en el rango E1:G17 de dicha hoja. Tengamos en cuenta que el rango empleado no puede incluir la celda donde se escribió la fórmula por que sino se generaría una referencia circular, por ejemplo si estamos en la "Hoja1", en la celda D6 no podríamos usar como rango D6:G17.

Contar veces que se repite un valor en varias hojas

De acuerdo al ejemplo anterior podemos emplear la suma de los valores de D6, D7 y D8 a fin obtener la cantidad de veces que aparece el valor "Tegucigalpa" en los rangos de las tres hojas.

De forma alternativa podemos emplear la fórmula:

=SUMAPRODUCTO(CONTAR.SI(INDIRECTO("'" & B6:B8 & "'!E1:G17"),B3))

Notemos que a diferencia de la anterior en lugar de hacer referencia solo a B6 (que contiene el texto "Hoja1") se hace referencia al conjunto de celdas que contiene la relación de hojas sobre las que se realizará el conteo, es decir esta parte de la fórmula retornará los valores; 1, 4 y 0.

Finalmente la función SUMAPRODUCTO nos retornará la suma de los valores que acaban de obtenerse.

Contar veces que se repite un valor por columnas

En los ejemplos anteriores podemos encontrar que se hace referencia a un rango de celdas definido donde se realizará la búsqueda, de forma alternativa podemos emplear:

=CONTAR.SI(INDIRECTO("Hoja2!A:XFD"),B3)

De esta forma se tomará en consideración dentro de la "Hoja2" desde la columna A, hasta la columna XFD.